timestepper.F90

Go to the documentation of this file.

 
module timestepper_mod
  use state_mod, only : model_state_type
  use grids_mod, only : x_index, y_index
  use registry_mod, only : group_type_whole, group_type_column, group_descriptor_type, get_ordered_groups, &
       execute_timestep_callbacks
  implicit none
 
#ifndef TEST_MODE
  private
#endif
 
  type(group_descriptor_type), dimension(:), allocatable :: group_descriptors
 
  public init_timestepper, timestep, finalise_timestepper
contains
 
  subroutine init_timestepper()
    call get_ordered_groups(group_descriptors)
  end subroutine init_timestepper  
 
  subroutine timestep(current_state)
    type(model_state_type), intent(inout) :: current_state
 
    integer :: i
 
    do i=1,size(group_descriptors)      
      if (group_descriptors(i)%type == group_type_whole) then
        call timestep_whole(current_state, group_descriptors(i))
      else if (group_descriptors(i)%type == group_type_column) then
        call timestep_column(current_state, group_descriptors(i))
      end if
    end do    
  end subroutine timestep
 
  subroutine finalise_timestepper()
    deallocate(group_descriptors)
  end subroutine finalise_timestepper  
 
  subroutine timestep_column(current_state, group_descriptor)
    type(model_state_type), intent(inout) :: current_state
    type(group_descriptor_type), intent(in) :: group_descriptor
 
    current_state%column_global_x=current_state%local_grid%start(x_index) - current_state%local_grid%halo_size(x_index)
    current_state%column_local_x=1
    do while (current_state%column_global_x .le. &
         current_state%local_grid%end(x_index)+current_state%local_grid%halo_size(x_index))
      current_state%column_global_y = current_state%local_grid%start(y_index) - current_state%local_grid%halo_size(y_index)
      current_state%column_local_y=1
      do while (current_state%column_global_y .le. &
           current_state%local_grid%end(y_index)+current_state%local_grid%halo_size(y_index))
        call update_state_sitation_flags(current_state)
        call execute_timestep_callbacks(current_state, group_descriptor%id)
        current_state%column_global_y = current_state%column_global_y + 1
        current_state%column_local_y = current_state%column_local_y + 1
      end do
      current_state%column_global_x = current_state%column_global_x + 1
      current_state%column_local_x = current_state%column_local_x + 1
    end do    
  end subroutine timestep_column
 
  subroutine timestep_whole(current_state, group_descriptor)
    type(model_state_type), intent(inout) :: current_state
    type(group_descriptor_type), intent(in) :: group_descriptor
 
    call execute_timestep_callbacks(current_state, group_descriptor%id)
  end subroutine timestep_whole
 
  subroutine update_state_sitation_flags(current_state)
    type(model_state_type), intent(inout) :: current_state
 
    current_state%first_timestep_column = (current_state%column_local_x == 1 .and. current_state%column_local_y == 1)
    current_state%last_timestep_column = (current_state%column_global_x == &
         current_state%local_grid%end(x_index) + current_state%local_grid%halo_size(x_index) .and. &
         current_state%column_global_y == current_state%local_grid%end(y_index) + current_state%local_grid%halo_size(y_index))   
 
    current_state%first_nonhalo_timestep_column = (current_state%column_local_x == current_state%local_grid%halo_size(x_index)+1 &
       .and. current_state%column_local_y == current_state%local_grid%halo_size(y_index)+1)
 
    current_state%halo_column = current_state%column_local_y .lt. current_state%local_grid%local_domain_start_index(y_index) .or.&
         current_state%column_local_x .lt. current_state%local_grid%local_domain_start_index(x_index) .or.&
         current_state%column_local_y .gt. current_state%local_grid%local_domain_end_index(y_index) .or.&
         current_state%column_local_x .gt. current_state%local_grid%local_domain_end_index(x_index)
  end subroutine update_state_sitation_flags
end module timestepper_mod