coriolis.F90

Go to the documentation of this file.

 
module coriolis_mod
  use datadefn_mod, only : default_precision
  use monc_component_mod, only : component_array_field_type, &
      component_double_data_type, component_descriptor_type, &
      component_field_value_type, component_field_information_type
  use optionsdatabase_mod, only : options_get_logical, options_get_real, options_get_integer
  use state_mod, only : model_state_type
  use grids_mod, only : z_index, y_index, x_index
  implicit none
 
#ifndef TEST_MODE
  private
#endif
 
  logical :: baroclinicity_use_geostrophic_shear
  real(kind=default_precision), dimension(:), allocatable :: geostrophic_wind_x, geostrophic_wind_y
  real(kind=default_precision) :: fcoriol
 
  ! Local tendency diagnostic variables for this component
  ! 3D tendency fields and logicals for their use
  real(kind=default_precision), dimension(:,:,:), allocatable ::     &
       tend_3d_u, tend_3d_v
  logical :: l_tend_3d_u, l_tend_3d_v
  ! Local mean tendency profile fields and logicals for their use
  real(kind=default_precision), dimension(:), allocatable ::         &
       tend_pr_tot_u, tend_pr_tot_v
  logical :: l_tend_pr_tot_u, l_tend_pr_tot_v
 
  integer :: diagnostic_generation_frequency
 
  public coriolis_get_descriptor
 
  contains
 
  type(component_descriptor_type) function coriolis_get_descriptor()
    coriolis_get_descriptor%name="coriolis"
    coriolis_get_descriptor%version=0.1
    coriolis_get_descriptor%initialisation=>initialisation_callback
    coriolis_get_descriptor%timestep=>timestep_callback
    coriolis_get_descriptor%finalisation=>finalisation_callback
 
    coriolis_get_descriptor%field_value_retrieval=>field_value_retrieval_callback
    coriolis_get_descriptor%field_information_retrieval=>field_information_retrieval_callback
    allocate(coriolis_get_descriptor%published_fields(2+2))
 
    coriolis_get_descriptor%published_fields(1)= "tend_u_coriolis_3d_local"
    coriolis_get_descriptor%published_fields(2)= "tend_v_coriolis_3d_local"
 
    coriolis_get_descriptor%published_fields(2+1)= "tend_u_coriolis_profile_total_local"
    coriolis_get_descriptor%published_fields(2+2)= "tend_v_coriolis_profile_total_local"
 
  end function coriolis_get_descriptor
 
 
  subroutine field_information_retrieval_callback(current_state, name, field_information)
    type(model_state_type), target, intent(inout) :: current_state
    character(len=*), intent(in) :: name
    type(component_field_information_type), intent(out) :: field_information
    integer :: strcomp
 
    ! Field information for 3d
    strcomp=index(name, "coriolis_3d_local")
    if (strcomp .ne. 0) then
      field_information%field_type=component_array_field_type
      field_information%number_dimensions=3
      field_information%dimension_sizes(1)=current_state%local_grid%size(z_index)
      field_information%dimension_sizes(2)=current_state%local_grid%size(y_index)
      field_information%dimension_sizes(3)=current_state%local_grid%size(x_index)
      field_information%data_type=component_double_data_type
 
      if      (name .eq. "tend_u_coriolis_3d_local") then
        field_information%enabled=l_tend_3d_u
      else if (name .eq. "tend_v_coriolis_3d_local") then
        field_information%enabled=l_tend_3d_v
      else
        field_information%enabled=.true.
      end if
 
    end if !end 3d check
 
    ! Field information for profiles
    strcomp=index(name, "coriolis_profile_total_local")
    if (strcomp .ne. 0) then
      field_information%field_type=component_array_field_type
      field_information%number_dimensions=1
      field_information%dimension_sizes(1)=current_state%local_grid%size(z_index)
      field_information%data_type=component_double_data_type
 
      if      (name .eq. "tend_u_coriolis_profile_total_local") then
        field_information%enabled=l_tend_pr_tot_u
      else if (name .eq. "tend_v_coriolis_profile_total_local") then
        field_information%enabled=l_tend_pr_tot_v
      else
        field_information%enabled=.true.
      end if
 
    end if !end profile check
 
  end subroutine field_information_retrieval_callback
 
 
  subroutine field_value_retrieval_callback(current_state, name, field_value)
    type(model_state_type), target, intent(inout) :: current_state
    character(len=*), intent(in) :: name
    type(component_field_value_type), intent(out) :: field_value
 
    ! 3d Tendency Fields
    if      (name .eq. "tend_u_coriolis_3d_local" .and. allocated(tend_3d_u)) then
      call set_published_field_value(field_value, real_3d_field=tend_3d_u)
    else if (name .eq. "tend_v_coriolis_3d_local" .and. allocated(tend_3d_v)) then
      call set_published_field_value(field_value, real_3d_field=tend_3d_v)
 
    ! Profile Tendency Fields
    else if (name .eq. "tend_u_coriolis_profile_total_local" .and. allocated(tend_pr_tot_u)) then
      call set_published_field_value(field_value, real_1d_field=tend_pr_tot_u)
    else if (name .eq. "tend_v_coriolis_profile_total_local" .and. allocated(tend_pr_tot_v)) then
      call set_published_field_value(field_value, real_1d_field=tend_pr_tot_v)
    end if
 
 
  end subroutine field_value_retrieval_callback
 
 
  subroutine initialisation_callback(current_state)
    type(model_state_type), target, intent(inout) :: current_state
 
    integer :: k
 
    baroclinicity_use_geostrophic_shear=options_get_logical(current_state%options_database, "baroclinicity_use_geostrophic_shear")
    fcoriol=options_get_real(current_state%options_database, "fcoriol")
    current_state%geostrophic_wind_rate_of_change_in_x=options_get_real(current_state%options_database, &
         "geostrophic_wind_rate_of_change_in_x")
    current_state%geostrophic_wind_rate_of_change_in_y=options_get_real(current_state%options_database, &
         "geostrophic_wind_rate_of_change_in_y")
    current_state%surface_geostrophic_wind_x=options_get_real(current_state%options_database, "surface_geostrophic_wind_x")
    current_state%surface_geostrophic_wind_y=options_get_real(current_state%options_database, "surface_geostrophic_wind_y")
 
    allocate(geostrophic_wind_x(current_state%local_grid%size(z_index)), &
         geostrophic_wind_y(current_state%local_grid%size(z_index)))
 
    do k=1,current_state%local_grid%size(z_index)
      geostrophic_wind_x(k)=current_state%surface_geostrophic_wind_x
      geostrophic_wind_y(k)=current_state%surface_geostrophic_wind_y
      if (baroclinicity_use_geostrophic_shear) then
        geostrophic_wind_x(k)=geostrophic_wind_x(k)+current_state%geostrophic_wind_rate_of_change_in_x*&
             current_state%global_grid%configuration%vertical%zn(k)
        geostrophic_wind_y(k)=geostrophic_wind_y(k)+current_state%geostrophic_wind_rate_of_change_in_y*&
             current_state%global_grid%configuration%vertical%zn(k)
      end if
    end do
 
    ! Tendency Logicals
    l_tend_pr_tot_u   = current_state%u%active
    l_tend_pr_tot_v   = current_state%v%active
 
    l_tend_3d_u   = current_state%u%active .or. l_tend_pr_tot_u
    l_tend_3d_v   = current_state%v%active .or. l_tend_pr_tot_v
 
    ! Allocate 3d tendency fields upon availability
    if (l_tend_3d_u) then
      allocate( tend_3d_u(current_state%local_grid%size(z_index),  &
                          current_state%local_grid%size(y_index),  &
                          current_state%local_grid%size(x_index)   )    )
    endif
    if (l_tend_3d_v) then
      allocate( tend_3d_v(current_state%local_grid%size(z_index),  &
                          current_state%local_grid%size(y_index),  &
                          current_state%local_grid%size(x_index)   )    )
    endif
 
    ! Allocate profile tendency fields upon availability
    if (l_tend_pr_tot_u) then
      allocate( tend_pr_tot_u(current_state%local_grid%size(z_index)) )
    endif
    if (l_tend_pr_tot_v) then
      allocate( tend_pr_tot_v(current_state%local_grid%size(z_index)) )
    endif
 
    ! Save the sampling_frequency to force diagnostic calculation on select time steps
    diagnostic_generation_frequency=options_get_integer(current_state%options_database, "sampling_frequency")
 
  end subroutine initialisation_callback
 
 
  subroutine finalisation_callback(current_state)
    type(model_state_type), target, intent(inout) :: current_state
 
    if (allocated(tend_3d_u)) deallocate(tend_3d_u)
    if (allocated(tend_3d_v)) deallocate(tend_3d_v)
 
    if (allocated(tend_pr_tot_u)) deallocate(tend_pr_tot_u)
    if (allocated(tend_pr_tot_v)) deallocate(tend_pr_tot_v)
 
  end subroutine finalisation_callback
 
  subroutine timestep_callback(current_state)
    type(model_state_type), target, intent(inout) :: current_state
 
    integer :: local_y, locaL_x, k, target_x_index, target_y_index
 
    local_y=current_state%column_local_y
    local_x=current_state%column_local_x
    target_y_index=local_y-current_state%local_grid%halo_size(y_index)
    target_x_index=local_x-current_state%local_grid%halo_size(x_index)
 
    ! Zero profile tendency totals on first instance in the sum
    if (current_state%first_timestep_column) then
      if (l_tend_pr_tot_u) then
        tend_pr_tot_u(:)= 0.0_default_precision
      endif
      if (l_tend_pr_tot_v) then
        tend_pr_tot_v(:)= 0.0_default_precision
      endif
    endif  ! zero totals
 
    if (current_state%halo_column) then
      if (.not. ((current_state%column_local_y == current_state%local_grid%halo_size(y_index) .and. &
           current_state%column_local_x .le. current_state%local_grid%local_domain_end_index(x_index) .and. &
           current_state%column_local_x .ge. current_state%local_grid%local_domain_start_index(x_index)-1) .or. &
           (current_state%column_local_x == current_state%local_grid%halo_size(x_index) .and. &
           current_state%column_local_y .ge. current_state%local_grid%local_domain_start_index(y_index) &
           .and. current_state%column_local_y .le. current_state%local_grid%local_domain_end_index(y_index)) )) return
    end if
 
    if (mod(current_state%timestep, diagnostic_generation_frequency) == 0 .and. .not. current_state%halo_column) then
      call save_precomponent_tendencies(current_state, local_x, local_y, target_x_index, target_y_index)
    end if
    
    do k=2,current_state%local_grid%size(z_index)
#if defined(U_ACTIVE) && defined(V_ACTIVE)
      current_state%su%data(k, current_state%column_local_y, current_state%column_local_x)=&
           current_state%su%data(k, current_state%column_local_y, current_state%column_local_x)+fcoriol*&
           (0.25_default_precision*(current_state%v%data(k, current_state%column_local_y, current_state%column_local_x)+&
           current_state%v%data(k, current_state%column_local_y, current_state%column_local_x+1)+&
           current_state%v%data(k, current_state%column_local_y-1, current_state%column_local_x)+&
           current_state%v%data(k, current_state%column_local_y-1, current_state%column_local_x+1))+current_state%vgal-&
           geostrophic_wind_y(k))
 
      current_state%sv%data(k, current_state%column_local_y, current_state%column_local_x)=&
           current_state%sv%data(k, current_state%column_local_y, current_state%column_local_x)-fcoriol*&
           (0.25_default_precision*(current_state%u%data(k, current_state%column_local_y, current_state%column_local_x)+&
           current_state%u%data(k, current_state%column_local_y, current_state%column_local_x-1)+&
           current_state%u%data(k, current_state%column_local_y+1, current_state%column_local_x)+&
           current_state%u%data(k, current_state%column_local_y+1, current_state%column_local_x-1))+current_state%ugal-&
           geostrophic_wind_x(k))
#endif
    end do
 
    if (mod(current_state%timestep, diagnostic_generation_frequency) == 0  .and. .not. current_state%halo_column) then
      call compute_component_tendencies(current_state, local_x, local_y, target_x_index, target_y_index)
    end if
 
  end subroutine timestep_callback
 
 
  subroutine save_precomponent_tendencies(current_state, cxn, cyn, txn, tyn)
    type(model_state_type), target, intent(in) :: current_state
    integer, intent(in) ::  cxn, cyn, txn, tyn
 
    ! Save 3d tendency fields upon request (of 3d or profiles) and availability
    if (l_tend_3d_u) then
      tend_3d_u(:,tyn,txn)=current_state%su%data(:,cyn,cxn)
    endif
    if (l_tend_3d_v) then
      tend_3d_v(:,tyn,txn)=current_state%sv%data(:,cyn,cxn)
    endif
 
  end subroutine save_precomponent_tendencies
 
 
  subroutine compute_component_tendencies(current_state, cxn, cyn, txn, tyn)
    type(model_state_type), target, intent(inout) :: current_state
    integer, intent(in) ::  cxn, cyn, txn, tyn
 
    ! Calculate change in tendency due to component
    if (l_tend_3d_u) then
      tend_3d_u(:,tyn,txn)=current_state%su%data(:,cyn,cxn) - tend_3d_u(:,tyn,txn)
    endif
    if (l_tend_3d_v) then
      tend_3d_v(:,tyn,txn)=current_state%sv%data(:,cyn,cxn) - tend_3d_v(:,tyn,txn)
    endif
 
   ! Add local tendency fields to the profile total
    if (l_tend_pr_tot_u) then
      tend_pr_tot_u(:)=tend_pr_tot_u(:) + tend_3d_u(:,tyn,txn)
    endif
    if (l_tend_pr_tot_v) then
      tend_pr_tot_v(:)=tend_pr_tot_v(:) + tend_3d_v(:,tyn,txn)
    endif
 
  end subroutine compute_component_tendencies
 
  subroutine set_published_field_value(field_value, real_1d_field, real_2d_field, real_3d_field)
    type(component_field_value_type), intent(inout) :: field_value
    real(kind=default_precision), dimension(:), optional :: real_1d_field
    real(kind=default_precision), dimension(:,:), optional :: real_2d_field
    real(kind=default_precision), dimension(:,:,:), optional :: real_3d_field
 
    if (present(real_1d_field)) then
      allocate(field_value%real_1d_array(size(real_1d_field)), source=real_1d_field)
    else if (present(real_2d_field)) then
      allocate(field_value%real_2d_array(size(real_2d_field, 1), size(real_2d_field, 2)), source=real_2d_field)
    else if (present(real_3d_field)) then
      allocate(field_value%real_3d_array(size(real_3d_field, 1), size(real_3d_field, 2), size(real_3d_field, 3)), &
               source=real_3d_field)
    end if
  end subroutine set_published_field_value
 
 
end module coriolis_mod