checkpointnetcdfparser.F90

Go to the documentation of this file.

 
module configuration_checkpoint_netcdf_parser_mod
  use datadefn_mod, only : string_length
  use collections_mod, only : hashmap_type
  use netcdf, only : nf90_nowrite, nf90_netcdf4, nf90_mpiio, nf90_noerr, nf90_strerror, nf90_open, nf90_close, &
       nf90_inq_dimid, nf90_inquire_dimension, nf90_inq_varid, nf90_get_var
  use logging_mod, only : log_error, log_master_log
  use conversions_mod, only : conv_is_integer, conv_to_integer, conv_is_real, conv_to_real, conv_is_logical, conv_to_logical, &
       conv_single_real_to_double
  use optionsdatabase_mod, only : options_add
  use mpi, only : mpi_info_null
  use netcdf_misc_mod, only : check_netcdf_status
  implicit none
 
#ifndef TEST_MODE
  private
#endif
 
  character(len=*), parameter :: options_key="options_database", &  !< The options key which references the configuration
       options_dim_key="number_options" 
 
  public parse_configuration_checkpoint_netcdf
contains
 
  subroutine parse_configuration_checkpoint_netcdf(options_database, checkpoint_name, communicator)
    type(hashmap_type), intent(inout) :: options_database
    character(*), intent(in) :: checkpoint_name
    integer, intent(in) :: communicator
 
    integer :: ncid
 
    call check_netcdf_status(nf90_open(path = checkpoint_name, mode = nf90_nowrite, ncid = ncid))
    call load_options(options_database, ncid)
    call check_netcdf_status(nf90_close(ncid))
  end subroutine parse_configuration_checkpoint_netcdf
 
  subroutine load_options(options_database, ncid)
    type(hashmap_type), intent(inout) :: options_database
    integer, intent(in) :: ncid
 
    integer :: i, options_id, number_options
    character(len=STRING_LENGTH) :: key, value
 
    number_options=get_number_of_options(ncid)
    call check_netcdf_status(nf90_inq_varid(ncid, options_key, options_id))
 
    do i=1, number_options
      call check_netcdf_status(nf90_get_var(ncid, options_id, key, (/ 1, 1, i /)))
      call check_netcdf_status(nf90_get_var(ncid, options_id, value, (/ 1, 2, i /)))
      ! NetCDF does C style null termination right at the end, need to remove this so can trim spaces etc
      call remove_null_terminator_from_string(key)
      call remove_null_terminator_from_string(value)
      if (conv_is_integer(trim(value))) then
        call options_add(options_database, trim(key), conv_to_integer(trim(value)))
      else if (conv_is_real(trim(value))) then
        call options_add(options_database, trim(key), conv_single_real_to_double(conv_to_real(trim(value))))
      else if (conv_is_logical(trim(value))) then
        call options_add(options_database, trim(key), conv_to_logical(trim(value)))
      else
        call options_add(options_database, trim(key), trim(value))
      end if
    end do
  end subroutine load_options
 
  subroutine remove_null_terminator_from_string(net_cdf_string)
    character(len=*), intent(inout) :: net_cdf_string
    integer :: i
    do i=1,len(net_cdf_string)
      if (iachar(net_cdf_string(i:i)) == 0) then
        net_cdf_string(i:len(net_cdf_string)) = ' '
        exit
      end if
    end do
  end subroutine remove_null_terminator_from_string
 
  integer function get_number_of_options(ncid)
    integer, intent(in) :: ncid
 
    integer :: options_dimid, options_dim
    call check_netcdf_status(nf90_inq_dimid(ncid, options_dim_key, options_dimid))
    call check_netcdf_status(nf90_inquire_dimension(ncid, options_dimid, len=options_dim))
    get_number_of_options=options_dim
  end function get_number_of_options
end module configuration_checkpoint_netcdf_parser_mod